编写命令行程序，参数的解析不可避免。然而，F# 基础库并没有提供对此的支持。不过，F# PowerPack 提供了一个简单的工具来帮助解析命令行参数。其使用优雅简单，符合 F# 描述型语言的特性。

首先，让我用一个模拟编译器命令行程序来展示下该工具的使用：

open Microsoft.FSharp.Text

let mutable output = "a.out"
let verbose = ref false
let mutable warningLevel = 0

let mutable objs:string list = []
let compile s =
    match !verbose with
    | false -> printfn "compiling %s ..." s
    | true -> printfn "compiling %s with -w %d ..." s warningLevel
    objs <- (sprintf "%s.o" s)::objs

let specs =
    [ ("-o",
       ArgType.String (fun s -> output <- s),
       "name of the output")
      ("-v",
       ArgType.Set verbose,
       "display addtional information")
      ("-w",
       ArgType.Int (fun i -> warningLevel <- i),
       "set warning level")
    ] |> List.map (fun (sh, ty, desc) -> ArgInfo(sh, ty, desc))

ArgParser.Parse(specs, compile)

match objs with
| [] -> printfn "no object files found!"
| _ ->
    printfn "linking ..."
    objs |> Set.ofList |> Set.iter (fun x -> printfn "-> %s" x)
    printfn "generate output %s" output

也就不用多解释了，F# 描述性的特性让我们很容易地就能看懂这段代码。让我们来看看此段代码的执行结果，注意，该工具自动生成了 --help 命令：

>CmdArg.exe a.c b.c
compiling a.c ...
compiling b.c ...
linking ...
-> a.c.o
-> b.c.o
generate output a.out

>CmdArg.exe -v a.c b.c
compiling a.c with -w 0 ...
compiling b.c with -w 0 ...
linking ...
-> a.c.o
-> b.c.o
generate output a.out

>CmdArg.exe -v -w 3 a.c b.c
compiling a.c with -w 3 ...
compiling b.c with -w 3 ...
linking ...
-> a.c.o
-> b.c.o
generate output a.out

>CmdArg.exe -v -w 3 -o test.exe a.c b.c
compiling a.c with -w 3 ...
compiling b.c with -w 3 ...
linking ...
-> a.c.o
-> b.c.o
generate output test.exe

>CmdArg.exe --help

        -o <string>: name of the output
        -v: display addtional information
        -w <int>: set warning level
        --help: display this list of options
        -help: display this list of options

该工具提供的参数类型并不多，简介如下：

• ArgType.Unit(f): 启动一个 unit -> unit 的回调函数
• ArgType.Set(b): 自动设置一个 bool ref 为 true
• ArgType.Clear(b): 自动设置一个 bool ref 为 false
• ArgType.String(f): 启动一个 string -> unit 的回调函数
• ArgType.Int(f): 启动一个 int -> unit 的回调函数
• ArgType.Float(f): 启动一个 float -> unit 的回调函数
• ArgType.Rest(f): 停止解析，对其后的每一个字符命令启动一个 string -> unit 的回调函数

就是这么简单！回想当年 C 时代，编写命令行参数解析的麻烦啊，呵呵。